윈도우 홈에서 gpedit.msc 로컬 그룹 정책 편집기 사용하는 방법

Windows를 사용하면서 자잘한 설정을 수정하게 되는데 대표적인 도구로는 Windows 설정, 레지스트리 편집기Registry Editor 그리고 로컬 그룹 정책 편집기Local Group Policy Editor등이 대표적입니다.

Windows 설정 앱은 간편하고 일반적인 설정 변경을 위한 좋은 옵션이지만, 고급 설정을 변경하려면 레지스트리 편집기 또는 로컬 그룹 정책 편집기를 고려해야 하는데, 구성이 한글화되어 있는 로컬 그룹 정책 편집기를 사용하는 것이 좀 더 편리할 수 있습니다. 로컬 그룹 정책 편집기 더 알아보기

gpedit-msc를-찾을-수-없습니다
gpedit msc를 찾을 수 없습니다

Windows Pro, Enterprise, 또는 Education 에디션이 아닌 Windows Home 에디션에서는 아쉽게도 이러한 고급 도구가 지원되지 않습니다. 따라서 Home Edition 사용자들은 추가적인 설정 조정을 위해 다른 방법을 찾아야 하는데, 이 때문에 일부 사용자들은 Pro나 Enterprise 버전으로 업그레이드를 고려하게 되는데 비용이 만만치 않아 선뜻 진행하기 부담이 될 수 있습니다. Windows 라이선스 더 알아보기

하지만 업그레이드 하지 않더라도, 몇 가지 비공식 방법을 통해 Home Edition에서도 로컬 그룹 정책 편집기를 활성화할 수 있는데, 이 중에서 가장 간편하고 안정적이라고 판단되는 방식을 하나 안내하려 합니다.

아래 설명은 informanual.com 에서 테스트 및 검증 후 작성 된 내용이지만 이것이 본문의 내용의 정확성이나 신뢰성에 대해 보증을 하는 것은 아니니 단순하게 참고용으로 확인바랍니다.

튜토리얼 환경: 윈도우 10 Home (빌드: 19045.2965)

install batch 파일 생성

로컬 그룹 정책 편집기를 사용하기 위해서는 Microsoft-Windows-GroupPolicy-ClientExtensions-Package 및 Microsoft-Windows-GroupPolicy-ClientTools-Package가 설치되어 있거나 업데이트가 되어야 합니다. 이를 간편하게 작업할 Batch 파일을 생성하는 과정입니다. Batch 파일 더 알아보기

주의: 아래 안내하는 방법은 기술적으로 가능하지만, Windows Home Edition에서 로컬 그룹 정책 편집기를 사용하는 것은 공식적으로 지원되지 않으므로 문제가 발생할 수 있습니다. 그러므로 위와 같은 작업을 수행하기 전에 반드시 시스템 백업을 하십시오.
메모장에-Batch-스크립트-작성
메모장에 Batch 스크립트 작성

메모장 또는 자주 사용하는 에디터를 열고 다음 명령을 작성합니다. 아래 명령은 Windows에서 그룹 정책 클라이언트 확장 및 도구 패키지를 설치하는 작업을 진행하게 됩니다.

@echo off
setlocal EnableDelayedExpansion

pushd "%~dp0"

> List.txt (
    dir /b "%SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum"
    dir /b "%SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~3*.mum"
)

for /f %%i in ('type List.txt 2^>nul') do (
    set "package=%SystemRoot%\servicing\Packages\%%i"
    dism /online /norestart /add-package:"!package!" 2>nul
    if !errorlevel! equ 0 (
        echo Installed: %%i
    ) else (
        echo Error installing: %%i
    )
)
pause

위 스크립트의 동작을 좀 더 알아보면 다음과 같습니다.

  • @echo off: 이 명령은 스크립트가 실행될 때 명령 프롬프트에 명령을 표시하지 않도록 합니다.
  • setlocal EnableDelayedExpansion: 이 명령은 확장된 변수 지역화를 활성화합니다. 이렇게 하면 반복문 내에서 변수를 수정할 수 있습니다
  • pushd %~dp0: 현재 스크립트가 위치한 디렉토리로 이동합니다.
  • dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum >List.txt: %SystemRoot%\servicing\Packages 경로에 있는 특정 패키지 파일을 찾아서 그 목록을 List.txt 파일에 저장합니다.
  • dir /b %SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~3*.mum >>List.txt: 또 다른 특정 패키지 파일을 찾아서 List.txt 파일에 목록을 추가합니다.
  • for /f %%i in(findstr /i . List.txt 2^>nul) do dism /online /norestart /add-package:%SystemRoot%\servicing\Packages\%%i: List.txt 파일에서 각 패키지 파일 이름을 반복하여 dism 도구를 사용하여 해당 패키지를 온라인으로 추가합니다. 이는 Windows 업데이트와 관련이 있을 수 있습니다. if !errorlevel! equ 0을 통해 dism 명령이 성공적으로 실행되었는지 확인하기 위해 errorlevel을 검사합니다. errorlevel0인 경우 명령이 성공적으로 실행되었다는 것을 의미합니다.
  • pause: 스크립트를 일시 중지하고 사용자의 입력을 기다립니다.
파일을-bat-확장자로-저장
파일을 bat 확장자로 저장

작성이 완료되면 파일의 이름과 확장자를 위와 같이 변경합니다. 파일 이름은 아무렇게나 지정해도 상관이 없지만 파일 확장자는 .bat으로 지정합니다. 필요한 경우 다음 버튼을 눌러 직접 생성해둔 파일을 내려받을 수도 있습니다.

bat-파일-생성-완료
bat 파일 생성 완료

Batch 파일은 위와 같은 형태의 아이콘으로 생성이 됩니다.

Excel 엑셀 인쇄 페이지 점선 가이드 선 제거하기

로컬 그룹 정책 편집기 설치

앞서 생성한 스크립트 파일을 실행하면 Windows Home 에디션에서 간단하게 로컬 그룹 정책 편집기를 사용할 수 있게 됩니다.

batch-파일-관리자-권한으로-실행
batch 파일 관리자 권한으로 실행

이 파일의 스크립트는 시스템 패키지를 설치하고 변경하기 때문에 관리자 권한이 필요합니다. 마우스 오른쪽 버튼으로 클릭해 컨텍스트 메뉴를 열고 관리자 권한으로 실행하면 설치가 자동으로 시작됩니다.

설치-진행
설치 진행

위와 같이 명령 프롬프트 창이 열리고 자동으로 알아서 작업이 진행됩니다. 중간에 잠시 멈춰있는 구간이 있는데 그대로 기다리면 되고, 계속하려면 아무 키나 누르십시오.라는 메시지가 출력되면 작업이 완료된 것이니 아무키나 눌러 창을 종료합니다.

로컬-그룹-정책-편집기-실행-완료
로컬 그룹 정책 편집기 실행 완료

검색 또는 실행 명령으로 gpedit.msc를 실행하면 위와 같이 Windows Home 에디션에서도 로컬 그룹 정책 편집기를 사용할 수 있게 되었습니다.

로컬 그룹 정책 편집기 삭제

위 스크립트로 설치한 로컬 그룹 정책 편집기를 초기 Windows 상태로 돌아가기 위해 삭제하려면, DISM 명령어에 /remove-package 옵션을 사용해야 합니다.

로컬-그룹-정책-편집기-제거-명령
로컬 그룹 정책 편집기 제거 명령

설치 시 제작한 방식과 동일하게 txt파일열고 다음 스크립트를 작성 한 뒤 .bat 이나 .cmd 확장자로 저장합니다.

@echo off
setlocal EnableDelayedExpansion

pushd "%~dp0"

> List.txt (
    dir /b "%SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientExtensions-Package~3*.mum"
    dir /b "%SystemRoot%\servicing\Packages\Microsoft-Windows-GroupPolicy-ClientTools-Package~3*.mum"
)

for /f %%i in ('type List.txt 2^>nul') do (
    set "package=%SystemRoot%\servicing\Packages\%%i"
    dism /online /norestart /remove-package:"!package!" 2>nul
    if !errorlevel! equ 0 (
        echo Removed: %%i
    ) else (
        echo Error removing: %%i
    )
)
pause

이 스크립트는 원래의 설치 스크립트와 매우 유사합니다. 단지 /add-package/remove-package로 바뀌었을 뿐입니다. 이 변경으로 인해 DISM은 해당 패키지를 제거하려고 시도합니다. 앞서 안내한 방식으로 Batch 파일을 생성하거나 아래 다운로드버튼으로 바로 내려받을 수 있습니다.

관련글

Leave a Comment